批处理实现自动关机s

批处理实现自动关机 收藏
view plaincopy to clipboardprint?
::批处理实现自动关机.BAT  
@ECHO off  
TITLE 自动关机程序 作者:Micro_lee  
 
:start  
CLS  
COLOR 0e  
::使用COLOR命令对控制台输出颜色进行更改  
MODE con: COLS=49 LINES=25  
::MODE语句为设定窗体的宽和高  
set tm1=%time:~0,2%  
set tm2=%time:~3,2%  
set tm3=%time:~6,2%  
ECHO    %date% %tm1%点%tm2%分%tm3%秒     
ECHO ┏━━━━━━━━━━━━━━━━━━━━━━┓  
ECHO ┃ 定时关机锁定批处理程序 Author:Micro_lee    ┃  
ECHO ┣━━━━━━━━━━━━━━━━━━━━━━┫  
ECHO ┃                                            ┃  
ECHO ┃ 1. 定时关机                                ┃  
ECHO ┃ 2. 倒计时关机                              ┃  
ECHO ┃ 3. 删除定时关机任务                        ┃  
ECHO ┃ 4. 查看任务状态                            ┃  
ECHO ┃ 5. 刷新当前时间                            ┃  
ECHO ┃ 6. 重新启动                                ┃  
ECHO ┃ 7. 锁定计算机                              ┃  
ECHO ┃ 8. 注销                                    ┃  
ECHO ┃ 9. 退出                                    ┃  
ECHO ┃                                            ┃  
ECHO ┃ 请选择要进行的操作然后按回车               ┃  
ECHO.┗━━━━━━━━━━━━━━━━━━━━━━┛  
:: 输出空行，即相当于输入一个回车   
 
:Cho   
SET Choice=  
SET /P Choice=请输入选择项(1-9):  
::设定变量"Choice"为用户输入的字符  
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%  
::如果输入大于1位,取第1位,比如输入132,则返回值为1  
ECHO.  
IF /I "%Choice%"=="1" GOTO SetHour  
IF /I "%Choice%"=="2" GOTO outtime  
IF /I "%Choice%"=="3" GOTO delAt  
IF /I "%Choice%"=="4" GOTO view  
IF /I "%Choice%"=="5" GOTO start  
IF /I "%Choice%"=="6" GOTO restart  
IF /I "%Choice%"=="7" GOTO lock  
IF /I "%Choice%"=="8" GOTO logoff  
IF /I "%Choice%"=="9" GOTO end  
::为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号  
::注意,IF语句需要双等于号  
::如果输入的字符不是以上数字,将返回重新输入  
ECHO 选择无效，请重新输入  
GOTO Cho  
ECHO.  
 
 
:SetHour  
CLS  
ECHO.  
SET ask=  
SET /p ask=是否设定为每天执行关机命令(y/n):  
IF NOT "%ask%"=="" SET ask=%ask:~0,1%  
::如果输入大于1位,取第1位,比如输入yxz,则返回值为y  
IF /I "%ask%"=="y" GOTO yes  
IF /I "%ask%"=="n" GOTO no  
GOTO SetHour  
 
:yes  
ECHO 请指定24小时制式时间,格式为 小时:分钟  
SET shutdowntime=  
SET /p shutdowntime=输入:  
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul  
::设定为每周的星期一至星期日,即为每天  
IF NOT errorlevel 1 GOTO ok  
::如果输入正确,就执行ok段的语句  
ECHO %shutdowntime% 不是标准的时间格式,请重新输入  
ECHO.  
GOTO yes  
 
:no  
ECHO 请指定24小时制式时间,格式为 小时:分钟  
SET shutdowntime=  
SET /p shutdowntime=输入:  
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul  
IF NOT errorlevel 1 GOTO ok  
ECHO %shutdowntime% 不是标准的时间格式,请重新输入  
ECHO.  
GOTO no  
 
:ok  
ECHO.  
SET h=%shutdowntime:~1,1%  
SET ah=%shutdowntime:~0,1%  
SET am=%shutdowntime:~2,2%  
SET bh=%shutdowntime:~0,2%  
SET bm=%shutdowntime:~3,2%  
IF "%h%"==":" (  
SET HM=%ah%时%am%分  
) ELSE (  
SET HM=%bh%时%bm%分)  
::如果输入h:mm则HM=h时mm分,否则HM=hh时mm分   
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭  
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭  
ECHO 设定完毕! 按任意键继续...  
PAUSE >nul  
GOTO start  
 
:outtime  
CLS  
ECHO.  
ECHO 请输入倒计时秒数  
ECHO ────────  
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)  
SET timed=  
SET /p timed=输入:  
tsshutdn %timed% /delay:0 /powerdown >nul  
IF not errorlevel 1 GOTO ok  
ECHO %timed% 是无效的关机时间,请重新输入  
ECHO.  
GOTO outtime  
 
:delAt  
cls  
echo.  
at /del /y  
echo 定时关机任务已取消,按任意键继续...  
pause >nul  
GOTO start  
 
:view  
MODE con: COLS=85 LINES=18  
COLOR 0e  
ECHO.  
at  
ECHO 按任意键继续...  
PAUSE >nul  
GOTO start  
 
:restart  
shutdown -r -t 0  
 
:lock  
rundll32.exe user32.dll,LockWorkStation  
goto start  
 
:logoff  
logoff  
 
:end  
exit 
::批处理实现自动关机.BAT
@ECHO off
TITLE 自动关机程序 作者:Micro_lee:start
CLS
COLOR 0e
::使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=49 LINES=25
::MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO    %date% %tm1%点%tm2%分%tm3%秒  
ECHO ┏━━━━━━━━━━━━━━━━━━━━━━┓
ECHO ┃ 定时关机锁定批处理程序 Author:Micro_lee    ┃
ECHO ┣━━━━━━━━━━━━━━━━━━━━━━┫
ECHO ┃                                            ┃
ECHO ┃ 1. 定时关机                                ┃
ECHO ┃ 2. 倒计时关机                              ┃
ECHO ┃ 3. 删除定时关机任务                        ┃
ECHO ┃ 4. 查看任务状态                            ┃
ECHO ┃ 5. 刷新当前时间                            ┃
ECHO ┃ 6. 重新启动                                ┃
ECHO ┃ 7. 锁定计算机                              ┃
ECHO ┃ 8. 注销                                    ┃
ECHO ┃ 9. 退出                                    ┃
ECHO ┃                                            ┃
ECHO ┃ 请选择要进行的操作然后按回车               ┃
ECHO.┗━━━━━━━━━━━━━━━━━━━━━━┛
:: 输出空行，即相当于输入一个回车 :Cho
SET Choice=
SET /P Choice=请输入选择项(1-9):
::设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
::如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
::为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
::注意,IF语句需要双等于号
::如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
GOTO Cho
ECHO.
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
::如果输入大于1位,取第1位,比如输入yxz,则返回值为y
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
::设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
::如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
::如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ────────
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start:view
MODE con: COLS=85 LINES=18
COLOR 0e
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start:restart
shutdown -r -t 0:lock
rundll32.exe user32.dll,LockWorkStation
goto start:logoff
logoff:end
exit 发表于 @ 2009年12月13日　14:41:00 | 评论( 0 ) | 编辑| 举报| 收藏 旧一篇:特殊 字符 | 新一篇:修复IE无法打开连接等问题的批处理
查看最新精华文章 请访问博客首页相关文章 本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/Micro_lee/archive/2009/12/14/4997792.aspx