[转载]U盘拒绝访问！！！--问题总有解决的方法。

@echo off
title 简易U盘病毒清理系统1.10
cls
color 1f
echo ************************************************************************
echo * *
echo * 欢迎使用梦之光芒简易U盘病毒清理系统1.10 *
echo * *
echo * 本程序为免费软件，任何个人可随意使用，但不得用于商业用途 *
echo * *
echo * 本程序允许随意传播，但任何对本程序更改版权后的传播均为侵权 *
echo * *
echo * 由于本程序以验证文件名的形式进行病毒的识别，所以会不定期升级 *
echo * *
echo * 获得程序升级请到作者个人主页：http://hi.baidu.com/monyer *
echo * *
echo * OICQ：2598841 Email：monyer@126.com *
echo * *
echo * 作者：Monyer（梦之光芒）于2006年11月29日 *
echo * *
echo ************************************************************************
pause
cls
echo 正在检测您系统中的可移动设备
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1,2 delims=" %%i in ('fsutil fsinfo drives^|find /v ""') do (
set genre=%%i
set genre=!genre:~-2!
for %%a in (!genre!) do (
fsutil fsinfo drivetype %%a | findstr "移动" >nul 2>nul && if /i not "%%a"=="A:" (
set drive=%%a
echo.
echo 找到可移动存储设备, 盘符为%%a ,请确定盘符正确性。若不正确请立即退出本程序。
echo.
pause
echo.
echo 正在处理U盘隐藏文件，请等待！
!drive!
attrib -r -h -s -a *.*
call :go
)
)
)
cls
echo 检测完毕!
pause
exit
:go
echo.
set /p choice=请选择(1=普通杀毒 2=终极杀毒（注意：终极杀毒将删除U盘所有可执行文件！有极强危险性，仅用于插入型病毒！慎用！） n=不查杀病毒仅安全模式进入U盘):
if /i "%choice%"=="1" goto putong
if /i "%choice%"=="2" goto zhongji
if /i "%choice%"=="n" goto nokill
goto go
:putong
cls
echo 开始进行普通病毒检测及清除
echo.
for %%b in (AdobeR.exe bittorrent.exe copy.exe desktop.exe desktop2.exe desktop.ini folder.exe ghost.bat host.exe msinfmgr.exe msvcr71.dll nethood.htm nethood.html RavMonE.exe RavMonLog rose.exe setup.pif SHE.exe sxs.exe SYSTEM.VER tel.xls.exe toy.exe window.exe win32.exe win33.exe) do if exist %%b del /f/s/q/a %%b
if exist RECYCLER Rmdir /s/q RECYCLER
goto :nokill
:zhongji
cls
echo 开始进行终极杀毒
echo.
echo 正在扫描删除批处理文件
echo.
if exist *.bat del /f/s/q/a *.bat
if exist *.cmd del /f/s/q/a *.cmd
echo 正在扫描删除可执行文件及动态连接库
echo.
if exist *.com del /f/s/q/a *.com
if exist *.dll del /f/s/q/a *.dll
if exist *.exe del /f/s/q/a *.exe
echo 正在扫描删除引导文件
echo.
if exist *.inf del /f/s/q/a *.inf
if exist *.pif del /f/s/q/a *.pif
echo 正在扫描删除嘘文件、屏保文件以及其他文件
echo.
if exist *.scf del /f/s/q/a *.scf
if exist *.scr del /f/s/q/a *.scr
if exist *.shb del /f/s/q/a *.shb
if exist *.shs del /f/s/q/a *.shs
if exist *.url del /f/s/q/a *.url
echo 所有文件扫描删除完成
echo.
goto :nokill
:nokill
echo.
echo 删除autorun.inf
if exist autorun.inf del /f/s/q/a autorun.inf
echo.
echo 结束资源管理器进程以消除U盘右键添加项
echo.
taskkill /F /im explorer.exe
echo.
echo 正在打开你的U盘。
echo.
echo 您的U盘已检测完毕！请手工结束本程序。
echo.
explorer.exe !drive!
goto theEnd
:theEnd
exit

注明：以上代码来自：http://www.panomics.cn/